Una Centrale DCC con Arduino e telecomando a raggi infrarossi

#include <IRremote.h> // use the library
int receiver = 11; // pin 1 of IR receiver to Arduino digital pin 11
IRrecv irrecv(receiver); // create instance of 'irrecv'
decode_results results;
 
void setup()
{
  Serial.begin(9600); // for serial monitor output
  irrecv.enableIRIn(); // Start the receiver
  pinMode(9, OUTPUT); // Pin 9 output
}
void loop()
{
  if (irrecv.decode(&results)) // have we received an IR signal?
  {
    Serial.println(results.value, HEX); // display it on serial monitor in hexadecimal
    irrecv.resume();// receive the next value
  }
 
}

// --------------------------------------
// i2c_scanner
//
// Version 1
//    This program (or code that looks like it)
//    can be found in many places.
//    For example on the Arduino.cc forum.
//    The original author is not know.
// Version 2, Juni 2012, Using Arduino 1.0.1
//     Adapted to be as simple as possible by Arduino.cc user Krodal
// Version 3, Feb 26  2013
//    V3 by louarnold
// Version 4, March 3, 2013, Using Arduino 1.0.3
//    by Arduino.cc user Krodal.
//    Changes by louarnold removed.
//    Scanning addresses changed from 0...127 to 1...119,
//    according to the i2c scanner by Nick Gammon
//    http://www.gammon.com.au/forum/?id=10896
// Version 5, March 28, 2013
//    As version 4, but address scans now to 127.
//    A sensor seems to use address 120.
// 
//
// This sketch tests the standard 7-bit addresses
// Devices with higher bit address might not be seen properly.
//
 
#include <Wire.h>
 
 
void setup()
{
  Wire.begin();
 
  Serial.begin(9600);
  Serial.println("\nI2C Scanner");
}
 
 
void loop()
{
  byte error, address;
  int nDevices;
 
  Serial.println("Scanning...");
 
  nDevices = 0;
  for(address = 1; address < 127; address++ ) 
  {
    // The i2c_scanner uses the return value of
    // the Write.endTransmisstion to see if
    // a device did acknowledge to the address.
    Wire.beginTransmission(address);
    error = Wire.endTransmission();
 
    if (error == 0)
    {
      Serial.print("I2C device found at address 0x");
      if (address<16) 
        Serial.print("0");
      Serial.print(address,HEX);
      Serial.println("  !");
 
      nDevices++;
    }
    else if (error==4) 
    {
      Serial.print("Unknow error at address 0x");
      if (address<16) 
        Serial.print("0");
      Serial.println(address,HEX);
    }    
  }
  if (nDevices == 0)
    Serial.println("No I2C devices found\n");
  else
    Serial.println("done\n");
 
  delay(5000);           // wait 5 seconds for next scan
}

/* YourDuino.com Example Software Sketch
 16 character 2 line I2C Display
 Backpack Interface labelled "A0 A1 A2" at lower right.
 ..and
 Backpack Interface labelled "YwRobot Arduino LCM1602 IIC V1"
 MOST use address 0x27, a FEW use 0x3F
 [email protected] */
 
/*-----( Import needed libraries )-----*/
#include <Wire.h>  // Comes with Arduino IDE
// Get the LCD I2C Library here: 
// https://bitbucket.org/fmalpartida/new-liquidcrystal/downloads
// Move any other LCD libraries to another folder or delete them
// See Library "Docs" folder for possible commands etc.
#include <LiquidCrystal_I2C.h>
 
/*-----( Declare Constants )-----*/
/*-----( Declare objects )-----*/
// set the LCD address to 0x27 for a 16 chars 2 line display
// A FEW use address 0x3F
// Set the pins on the I2C chip used for LCD connections:
//                    addr, en,rw,rs,d4,d5,d6,d7,bl,blpol
LiquidCrystal_I2C lcd(0x3F, 2, 1, 0, 4, 5, 6, 7, 3, POSITIVE);  // Set the LCD I2C address
 
/*-----( Declare Variables )-----*/
//NONE
 
void setup()   /*----( SETUP: RUNS ONCE )----*/
{
  Serial.begin(9600);  // Used to type in characters
 
  lcd.begin(16,2);   // initialize the lcd for 16 chars 2 lines, turn on backlight
 
// ------- Quick 3 blinks of backlight  -------------
  for(int i = 0; i< 3; i++) { lcd.backlight(); delay(250); lcd.noBacklight(); delay(250); } lcd.backlight(); // finish with backlight on //-------- Write characters on the display ------------------ // NOTE: Cursor Position: (CHAR, LINE) start at 0 lcd.setCursor(0,0); //Start at character 4 on line 0 lcd.print("Hello, world!"); delay(1000); lcd.setCursor(0,1); lcd.print("HI!YourDuino.com"); delay(8000); // Wait and then tell user they can start the Serial Monitor and type in characters to // Display. (Set Serial Monitor option to "No Line Ending") lcd.clear(); lcd.setCursor(0,0); //Start at character 0 on line 0 lcd.print("Use Serial Mon"); lcd.setCursor(0,1); lcd.print("Type to display"); }/*--(end setup )---*/ void loop() /*----( LOOP: RUNS CONSTANTLY )----*/ { { // when characters arrive over the serial port... if (Serial.available()) { // wait a bit for the entire message to arrive delay(100); // clear the screen lcd.clear(); // read all the available characters while (Serial.available() > 0) {
        // display each character to the LCD
        lcd.write(Serial.read());
      }
    }
  }
 
}/* --(end main loop )-- */
 
 
/* ( THE END ) */

/*
 d. bodnar  9-23-2014
 Uses 2 line LCD for display
 Uses IR remote control for throttle & functions (functions not working well yet)
 Uses CmdArduino library for DCC output
 
 UP = faster - 13 - hold to repeat
 DN = slower - 17 -hold to repeat
 * = STOP - 11
 # = Disable / enable DCC (pin 8) -12
 < = - 14
 > = -16
 OK = Menu choices -15
 */
// the following defines the codes for Keyes brand Sony and Nec IR remote controls
//#define KeyesUp 0xFF629D
#define SonyUp 0x90
#define NecUp 0xFFA857
//#define KeyesLeft 0xFF22DD
#define SonyLeft 0xC90
#define NecLeft 0xFF22DD
//#define KeyesOK 0xFF02FD
#define SonyMenu 0x70
#define NecEQ 0xFF906F
//#define KeyesRight 0xFFC23D
#define SonyRight 0x490
#define NecRight 0xFF02FD
//#define KeyesDown 0xFFA857
#define SonyDown 0x890
#define NecDown 0xFFE01F
//#define Keyes1 0xFF6897
#define Sony1 0x10
#define Nec1 0xFF30CF
//#define Keyes2 0xFF9867
#define Sony2 0x810
#define Nec2 0xFF18E7
//#define Keyes3 0xFFB04F
#define Sony3 0x410
#define Nec3 0xFF7A85
//#define Keyes4 0xFF30CF
#define Sony4 0xC10
#define Nec4 0xFF10EF
//#define Keyes5 0xFF18E7
#define Sony5 0x210
#define Nec5 0xFF38C7
//#define Keyes6 0xFF7A85
#define Sony6 0xA10
#define Nec6 0xFF5AA5
//#define Keyes7 0xFF10EF
#define Sony7 0x610
#define Nec7 0xFF42BD
//#define Keyes8 0xFF38C7
#define Sony8 0xE10
#define Nec8 0xFF4Ab5
//#define Keyes9 0xFF5AA5
#define Sony9 0x110
#define Nec9 0xFF52AD
//#define Keyes0 0xFF4AB5
#define Sony0 0x910
#define Nec0 0xFF6897
//#define KeyesStar 0xFF42BD
#define SonyExit 0xC70
#define NecExit 0xFFC23D
//#define KeyesPound 0xFF52AD
#define SonyPower 0xA90 
#define NecCh 0xFF629D
#include<EEPROM.h>
int irButton;
int LED = 13; // LED to blink when DCC packets are sent in loop
#include <IRremote.h>
int RECV_PIN = 11;
int Enable_PIN = 8; //low to enable DCC, high to stop
IRrecv irrecv(RECV_PIN);
decode_results results;
#include <DCCPacket.h>
#include <DCCPacketQueue.h>
#include <DCCPacketScheduler.h>
DCCPacketScheduler dps;
//unsigned int analog_value=0;
char speed_byte, old_speed = 0;
char temp;
byte Fx = 0;
byte DCCAddress = 3;
int irCode = 0;
int inMenu = 0;  // keeps track of being in the menu area 0=out, 1=in
int digits = 0;
int upFlag = 0;  // trying to get keys to repeat!
int dnFlag = 0;
#include <Wire.h>
#include <LCD.h>
#include <LiquidCrystal_I2C.h>
#define I2C_ADDR    0x3F // <<----- Add your address here.  Find it from I2C Scanner
#define BACKLIGHT_PIN     3
#define En_pin  2
#define Rw_pin  1
#define Rs_pin  0
#define D4_pin  4
#define D5_pin  5
#define D6_pin  6
#define D7_pin  7
byte fn0to4 = 0;  // DCC function variables
byte fn5to8 = 0;
byte fn9to12 = 0;
LiquidCrystal_I2C  lcd(I2C_ADDR,En_pin,Rw_pin,Rs_pin,D4_pin,D5_pin,D6_pin,D7_pin);
unsigned long previousMillis = 0; // last time update
long interval = 2000; // interval at which to do refresh (milliseconds)
 
void setup() {
  pinMode(LED, OUTPUT);
  DCCAddress = EEPROM.read(0);  
  if(DCCAddress >=100){  // set defalut as 3 if not in proper range (0-99)
    DCCAddress = 3;
  }
  pinMode(Enable_PIN, OUTPUT); 
  lcd.begin (16,2); //  LCD is 16 characters x 2 lines  
  lcd.setBacklightPin(BACKLIGHT_PIN,POSITIVE);
  lcd.setBacklight(HIGH);  // Switch on the backlight
  lcd.home (); // go home
  Serial.begin(115200);
  lcd.setCursor(0,0);  
  lcd.print("Version 2.7 ");
  lcd.setCursor(0,1);
  lcd.print("9-23-2014 ");
  delay(1500);
  lcd.clear();
  irrecv.enableIRIn(); // Start the receiver
  dps.setup();
  dps.setFunctions0to4(DCCAddress,DCC_SHORT_ADDRESS, B00000000); //clear functions
  dps.setFunctions5to8(DCCAddress,DCC_SHORT_ADDRESS, B00000000);    
}
 
void loop() {
  //this section sends DCC updates every 2 seconds (interval)
  // not sure if it is necessary but the functions are slow to respond
  // at times - may be due to the DCC library setting priorities as the
  // speed controls always work 
  unsigned long currentMillis = millis();
  if(currentMillis - previousMillis > interval) {
    previousMillis = currentMillis;  
    dps.setSpeed128(DCCAddress,DCC_SHORT_ADDRESS,speed_byte);
    dps.setFunctions0to4(DCCAddress,DCC_SHORT_ADDRESS, fn0to4); //clear all functions
    dps.setFunctions5to8(DCCAddress,DCC_SHORT_ADDRESS, fn5to8); 
    digitalWrite(LED, !digitalRead(LED));
  }
 
  digitalWrite(Enable_PIN, LOW);// HIGH = disable DCC
  lcd.setCursor(0,0);  
  lcd.print("Speed=");
  lcd.print(speed_byte, DEC);
  lcd.print("   ");  
  lcd.setCursor(11,0);
  lcd.print("ad=");
  if(DCCAddress <=9){
    lcd.print("0");  // add leading zero for single digit addresses 
  }
  lcd.print(DCCAddress, DEC);
  lcd.setCursor (14,1);        // go to end of 2nd line
  //  lcd.print("IR code ");
  lcd.print(irButton, DEC);
  lcd.print("       ");
  lcd.setCursor(5,1);// start of 2nd line
  // pad with leading zeros  
  String temp = "0000" + String(fn0to4,BIN);
  int tlen= temp.length() - 5;
  lcd.print(temp.substring(tlen));
  temp = "000" + String(fn5to8,BIN);
  tlen= temp.length() - 4;
  lcd.setCursor(0,1);// start of 2nd line
  lcd.print(temp.substring(tlen));
 
  if (irrecv.decode(&results)) 
  {
    translateIR();
    Serial.println(irButton,DEC);
    irrecv.resume(); // Receive the next value
  }
  byte button_state = digitalRead(4); //high == not pushed; low == pushed
  if ((irButton >0 && irButton <13) | (irButton ==14 | irButton == 16)){
    upFlag=0;
    dnFlag=0; ////MAY NEED TO PUT THIS ON EACH KEY 
  }
 
  if(irButton >=1 && irButton <=10){  //Funtions done with numbers 1-9 - clear all with 10
    doFunction();
    irButton=0;
  }
 
  // MENU SECTION - stays here to get DCC address 
  if (irButton==15 )  //OK key for menu choices
  {
    Serial.println("found OK (menu)");
    inMenu=1;
    lcd.clear(); // blank screen
    lcd.setCursor(0,0);  
    lcd.print("MENU");
    lcd.setCursor(0,1);
    lcd.print("Ent 2 digit add");
 
    for (int i =0; i = 1; i++){  // do twice
      if (irrecv.decode(&results)) 
      {
        translateIR();
        irrecv.resume(); // Receive the next value
      }     
      if (irButton == 15 && inMenu == 0){
        Serial.print("BREAK OUT ");
        Serial.println(inMenu, DEC);
        inMenu=0;
        irButton=0;
        digits=0;
        lcd.clear();
        break;
      }
      if (irButton >=1 && irButton <=10)
      {       
        if (digits==1){
          DCCAddress = DCCAddress * 10;
          Serial.print("x10 address ");
          Serial.println(DCCAddress, DEC);
          if(irButton != 10){   // only add it not zero (zero button or remote returns a 10)
            DCCAddress = DCCAddress + irButton;  
          }
          lcd.setCursor(0,1);
          if(DCCAddress <=9){
            lcd.print("0");  // add leading zero for single digit addresses 
          }
          lcd.print(DCCAddress, DEC);
          lcd.setCursor(0,0);
          lcd.print("OK to Exit Menu:");
          digits = 3;
          inMenu=0;
          EEPROM.write(0,DCCAddress);
        }       
        if (digits ==0){
          DCCAddress = irButton;
          if (DCCAddress==10){
            DCCAddress = 0;   // "0" button returns 10 so make it zero
          }
          Serial.print("dig 1 address ");
          Serial.println(DCCAddress, DEC);
          lcd.clear(); // blank screen
          lcd.setCursor(0,0);  
          lcd.print("New Address");
          lcd.setCursor(0,1);
          lcd.print(DCCAddress, DEC);
          digits = 1;  
          delay(500);
          irButton=0;        
        } 
        Serial.print("new address ");
        Serial.println(DCCAddress, DEC);
      }
      irButton=0;   
    }
    irButton=0;
  }
  //END MENU SECTION  
 
  if (irButton==13 | (irButton==99 && upFlag==1)) // repeat key (99)
  {
    Serial.println("found UP");
    speed_byte++;  
    upFlag=1;
    dnFlag=0;
    irButton=0;
  }
  if (irButton==16)
  {
    Serial.println("found UP ");
    speed_byte++;  
    irButton=0;
  }
  if (irButton ==17 | (irButton==99 && dnFlag==1))
  {
    Serial.println("found DN");
    speed_byte--; 
    dnFlag=1;
    upFlag = 0;
    irButton=0;
  }
  if (irButton ==14)
  {
    Serial.println("found DN ");
    speed_byte--; 
    irButton=0;
  }
  if (irButton==11)  //* key  - does STOP
  {
    Serial.println("found ***");
    speed_byte=0; 
    irButton=0; 
  }
  //Functions will not work without this to limit speed command to only new speeds
  if(speed_byte != old_speed)
  {
    speed_byte = constrain(speed_byte, -127, 127);
    dps.setSpeed128(DCCAddress,DCC_SHORT_ADDRESS,speed_byte);
    old_speed = speed_byte;
  } 
  dps.update();
}  //END LOOP
 
int translateIR() // takes action based on IR code received
// describing KEYES Remote IR codes (first) and Sony IR codes (second)
{
  Serial.println(results.value, HEX);
  switch(results.value)
  {
  //case KeyesUp:   //Keyes remote code for UP
  case SonyUp: //Sony remote code for UP
  case NecUp:   //Nec remote code for UP
    Serial.println(" UP"); 
    irButton = 13; 
    break;
  //case KeyesLeft:
  case SonyLeft:
  case NecLeft:
    Serial.println(" LEFT"); 
    irButton = 14;   
    break;
  //case KeyesOK:
  case SonyMenu:
  case NecEQ: 
    Serial.println(" -MENU-");
    irButton = 15;    
    break;
  //case KeyesRight:
  case SonyRight:
  case NecRight: 
    Serial.println(" RIGHT");
    irButton = 16;   
    break;
  //case KeyesDown:
  case SonyDown:
  case NecDown:
    Serial.println(" DOWN");
    irButton = 17; 
    break;
  //case Keyes1:
  case Sony1:
  case Nec1: 
    Serial.println(" 1"); 
    irButton = 1;   
    break;
  //case Keyes2:
  case Sony2:
  case Nec2: 
    Serial.println(" 2"); 
    irButton = 2;   
    break;
  //case Keyes3:
  case Sony3:
  case Nec3: 
    Serial.println(" 3"); 
    irButton = 3;   
    break;
  //case Keyes4:
  case Sony4:
  case Nec4: 
    Serial.println(" 4"); 
    irButton = 4;   
    break;
  //case Keyes5:
  case Sony5:
  case Nec5: 
    Serial.println(" 5"); 
    irButton = 5;   
    break;
  //case Keyes6:
  case Sony6:
  case Nec6: 
    Serial.println(" 6"); 
    irButton = 6;   
    break;
  //case Keyes7:
  case Sony7:
  case Nec7: 
    Serial.println(" 7"); 
    irButton = 7;   
    break;
  //case Keyes8:
  case Sony8:
  case Nec8: 
    Serial.println(" 8"); 
    irButton = 8;   
    break;
  //case Keyes9:
  case Sony9:
  case Nec9: 
    Serial.println(" 9"); 
    irButton = 9;   
    break;
  //case Keyes0:
  case Sony0:
  case Nec0: 
    Serial.println(" 0"); 
    irButton = 10;   
    break;
  //case KeyesStar:
  case NecExit:
    Serial.println(" *"); 
    irButton = 11;   
    break;
  case SonyExit:  //EXIT
    Serial.println(" *"); 
    irButton = 11;   
    break;
  //case KeyesPound:
  case NecCh: 
    Serial.println(" #"); 
    irButton = 12;   
    break;
  case SonyPower:  //POWER
    Serial.println(" #"); 
    irButton = 12;   
    break;
  case 0xFFFFFFFF: 
    Serial.println(" REPEAT");
    irButton = 99;
    break;  
  default: 
    Serial.println(" other button   ");
    irButton = 99;
  }// End Case
  delay(100); // Do not get immediate repeat
} //END translateIR
 
//START DO FUNCTION BUTTONS
int doFunction(){
  int irTemp= irButton-1;
  lcd.setCursor (14,1);        // go to end of 2nd line
  ///  lcd.print("FN code ");
  lcd.print(irButton, DEC);
  Serial.print("got a keypad button ");
  Serial.println(irButton,DEC);
  if (irTemp<=4){
    if(bitRead(fn0to4,irTemp)== 0 ){
      bitWrite(fn0to4,irTemp,1); 
    } 
    else {
      if(bitRead(fn0to4,irTemp)== 1 ){
        bitWrite(fn0to4,irTemp,0);       
      }
    } 
    dps.setFunctions0to4(DCCAddress,DCC_SHORT_ADDRESS,fn0to4);
    Serial.print(fn0to4,BIN);
    Serial.println(" fn0to4");
  }
 
  if (irTemp>=5 && irTemp<=8){
    irTemp=irTemp-5;
    if(bitRead(fn5to8,irTemp)== 0 ){
      bitWrite(fn5to8,irTemp,1); 
    } 
    else {
      if(bitRead(fn5to8,irTemp)== 1 ){
        bitWrite(fn5to8,irTemp,0);       
      }
    } 
    dps.setFunctions5to8(DCCAddress,DCC_SHORT_ADDRESS,fn5to8);
    Serial.print(fn5to8,BIN);
    Serial.println(" fn5to8");
  }
 
  if (irButton == 10)
  {
    lcd.setCursor (14,1);        // go to end of 2nd line
    ///    lcd.print("FN code ");
    lcd.print(irButton, DEC);
    Serial.println("got a keypad button 0 (reads as 10)");
    dps.setFunctions0to4(DCCAddress,DCC_SHORT_ADDRESS, B00000000); 
    dps.setFunctions5to8(DCCAddress,DCC_SHORT_ADDRESS, B00000000);    
    irButton = 0;
    fn0to4 = B00000000; //clear variables for which functions are set
    fn5to8 = B00000000;
    delay(500);
    irButton=0;
  }
  irButton = 0;
  delay(500);
}
//END DO FUNCTION BUTTONS

//#define KeyesUp 0xFF629D
#define SonyUp 0x90
#define NecUp 0xFFA857

//case KeyesUp:   //Keyes remote code for UP
  case SonyUp: //Sony remote code for UP
  case NecUp:   //Nec remote code for UP
    Serial.println(" UP"); 
    irButton = 13; 
    break;

#define I2C_ADDR    0x3F // <<----- Add your address here.  Find it from I2C Scanner